1  REM *** MODIFIED 11-98
10 REM   ***********  ICAO EXTENDED ATMOSPHERE MODEL   ************
20 REM          ALTITUDE H UP TO 400,000 FEET
30 REM input hft, output rho=density in slugs per cubic foot
40 REM                 tr=temp in deg rankine
50 REM                 p=pressure in lbs per sq foot
60 REM                 afps=speed of sound in ft per sec
70 REM all variables are double precision
72 COLOR 15,1
74 CLS
76 PRINT "   ICAO EXTENDED ATMOSPHERE MODEL   - UP TO 400,000 FEET"
78 PRINT
80 INPUT "      Input altitude in feet   ",HFT#
82 PRINT
90 IF (HFT#>= 36089!) GOTO 150
100 TMB#=518.688
110 ALM#=-3.56616E-03
120 HB#=0!
130 PB#=2116.21695#
140 GOTO 480
150 IF (HFT#>=82021!) GOTO 210
160 TMB#=389.998
170 ALM#=0!
180 HB#=36089!
190 PB#=472.679
200 GOTO 480
210 IF (HFT#>=154199!) GOTO 270
220 TMB#=389.988
230 ALM#=1.64592E-03
240 HB#=82021!
250 PB#=51.977
260 GOTO 480
270 IF (HFT#>=173884!) GOTO 330
280 TMB#=508.788
290 ALM#=0!
300 HB#=154199!
310 PB#=2.5155
320 GOTO 480
330 IF (HFT#>=246063!) GOTO 390
340 TMB#=508.788
350 ALM#=-.0021397
360 HB#=173884!
370 PB#=1.2181
380 GOTO 480
390 IF (HFT#>=295276!) GOTO 430
400 TMB#=354.348
410 REM data not available for alm,hb,and pb
420 GOTO 480
430 TMB#=354.348
440 ALM#=1.92024E-03
450 HB#=295276!
460 PB#=.0047825
470 REM   calculate output
480 TRANK#=TMB#+ALM#*(HFT#-HB#)
490 QA#=.018744
500 IF (ALM#=0!) GOTO 530
510 P#=PB#*((TMB#/TRANK#)^(QA#/ALM#))
520 GOTO 540
530 P#=PB#*EXP(-QA#*(HFT#-HB#)/TMB#)
540 RHO#=5.8259E-04*P#/TRANK#
550 AFPS#=49.021177#*SQR(TRANK#)
555 VISC#=0.317*TRANK#^1.5*(734.7/(TRANK#+216.))/EXP10(10.)
556 CLS
557 PRINT "   ICAO EXTENDED ATMOSPHERE MODEL"
558 PRINT
570 PRINT USING "Altitude       ######.#";HFT#;
572 PRINT USING "     ft               ######.#";HFT#*0.3048;
574 PRINT "    m"
580 PRINT USING "Speed of sound ####.###";AFPS#;
582 PRINT USING "     ft/s             ####.###";AFPS#*0.3048;
584 PRINT "    m/s"
590 PRINT USING "Density        #.####^^^^";RHO#;
592 PRINT USING "   slugs/cubic ft   #.####^^^^";RHO#*515.24;
594 PRINT "  kg/cubic m"
600 PRINT USING "Temperature     ####.#";TRANK#;
602 PRINT USING "      deg Rankine      ####.#";0.55556*TRANK#;
604 PRINT "      deg Kelvin"
610 PRINT USING "Pressure       ####.##";P#;
612 PRINT USING "      lb/sqf           ######.";P#*47.88;
614 PRINT "     N/sqm (Pa)"
615 PRINT USING "Viscosity      #.####^^^^";visc#;
617 PRINT USING "   sl/ft/s          #.####^^^^";visc#*47.87;
618 PRINT "  kg/m/s"
619 locate 22,1
620 INPUT "      Input another altitude in feet (0 to exit)  ",HFT#
622 if hft#>0. then
624 CLS
626 PRINT "   ICAO EXTENDED ATMOSPHERE MODEL   - UP TO 400,000 FEET"
628 PRINT
630 GOTO 90
632 END IF
640 cls
642 END